Дата и время в командной строке

[Naked]

Такой вопрос, если дата выводится в формате: День недели Дата. Например Thu 02/06/2005. можно ли как-нибудь убрать день недели при выводе из bat'файла. %date% выводит вместе с днем недели...

[crawler]

echo %date:~4%

[Naked]

А можно например поставить условие: если %user%=какому-то определённому, то делать какие-то действия

[Borland]

The_naked:
если %user%=какому-то определённому, то делать какие-то действия

IF "%UserName%"=="VasyaPupkin" CALL DoSomething.bat

The_naked:Там вроде не =, а ==

Поправил...

[Naked]

Сообщение от Borland

IF %UserName%=VasyaPupkin CALL DoSomething.bat

Там вроде не =, а ==, а так thanks

[Naked]

А можно как-нибудь убрать лишний пробел перед временем? Например, когда количество часов 2 знака (10-23), то в выходном файле один пробел, а когда 1 знак (0-9) в выходном файле 2 пробела, видимо один пробел из-за того, что должен писаться ноль (00-09), но он не пишется, как можно избавиться от этого пробела?

[crawler]

Ну немного напрягись сам.
if "%time:~0,1%"==" " echo %time:~1%

[Borland]

Сообщение от crawler

if "%time:~0,1%"==" " echo %time:~1%

Решил поделиться своим решением.

Как-то для целей резервного копирования мне понадобились дата и время в имени файла в формате "YYYYMMDD_HHMMSS", причём без пробелов. Для решения задачи была применена следующая конструкция:

if "%TIME:~0,1%"==" " (
set "DTSTRING=%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%_0%TIME:~1,1%%TIME:~3,2%%TIME:~6,2%"
) else (
set "DTSTRING=%DATE:~6,4%%DATE:~3,2%%DATE:~0,2%_%TIME:~0,2%%TIME:~3,2%%TIME:~6,2%"
)

которая всегда выдаёт15-значную переменную (при стандартных для русского языка шаблонах для даты "dd.MM.yyyy" и для времени "hh:mm:ss в региональных настройках системы), соответствующую дате и времени на момент запуска пакетного файла.
Слегка громоздко, зато надёжно.

[Borland]

Добавим получение даты и времени независимо от системных настроек:

@echo OFF

call :GETTIMESTAMP TIMESTAMP
echo %TIMESTAMP:~0,4%-%TIMESTAMP:~4,2%-%TIMESTAMP:~6,2% %TIMESTAMP:~8,2%:%TIMESTAMP:~10,2%:%TIMESTAMP:~12,2%
pause
goto :EOF

:GETTIMESTAMP
for /f "usebackq tokens=2 delims==" %%A in (`wmic os get LocalDateTime /value`) do set "%~1=%%A"
goto :EOF

И до кучи - получение даты/времени UTC (т.е. независимых от местного часового пояса)

@echo OFF
setlocal EnableDelayedExpansion

call :GETUTCTIMESTAMP TIMESTAMP
echo %TIMESTAMP%
pause
goto :EOF

:GETUTCTIMESTAMP
for /f "usebackq tokens=1,2 delims==" %%A in (`wmic path Win32_UTCTime get year^,month^,day^,hour^,minute^,second /value ^| find "="`) do (
    set /a TMPVAL=%%B  
    if !TMPVAL! LSS 10 (
        set UTC_%%A=0%%B
    ) else (
        set UTC_%%A=%%B
    )
)
set %1=%UTC_Year%-%UTC_Month%-%UTC_Day%T%UTC_Hour%:%UTC_Minute%:%UTC_Second%Z
goto :EOF

Данные "таймштампы" пригодятся, в частности, для скриптов, ведущих логи выполнения.